2nd Annual Robo-Reindeer Rumble competition!

jstrout

Robo Reindeer Rumble is a free programming game hosted at MiniScript.org. Six robotic reindeer duke it out with snowballs and meadow mines, each controlled by a (usually short) MiniScript program. The last reindeer standing wins! Every December we have a global competition to see who can program the most effective reindeer. Last year's competition was one by robot "Losx" by forum user @slobin. Who will reign this year?

To participate, post your entry in this thread. Be sure to tell us its name (or include it as a comment at the top). I'll live-stream the competition at least twice before the end of the month, before declaring a winner. So flex your fingers, sharpen your wits, and get ready to start slinging snowballs and dropping meadow mines!

jstrout

No takers this year? Has no one the courage and conviction to let their robo-reindeer rumble?!

maxkratt

I have one, it isn't a winner though lol.
I'll post it today hopefully, are multiple entries allowed?

maxkratt

I (not so proudly 😅) present Roundabout Rosy (Rangifer vertiginem)

// Name: Roundabout Rosy (Rangifer vertiginem)
print "Wheeee!"

speed = 20
tick = 0
rotation = 4
while deerCount > 1
    if rnd * 100 > 1 then
        speed = 10 + rnd(15)
    end if
    tick = tick + 1
    heading = heading + rotation - 1
    lastTick = floor((tick - 1) / 120)
    if lastTick != floor(tick / 120) then
        rotation = sign(rotation) * -4
    end if
    
    target = look
    if target then
        if target.speed < 20 and target.distance <= 50 then
            if deerCount == 2 then
                if target.health <= energy then 
                    throw target.health
                else
                    throw energy - 6
                end if
            else
                if target.health <= energy - 6 then
                    throw target.health
                else
                    throw energy - 6
                end if
            end if
        end if    
    end if
    yield
end while

maxkratt

Aaaand... Her wily cousin Simon

// Name: Snakey Simon (Rangifer serpens)
print "Hiss"

speed = 70
ticks = 0
rotation = 4
boxEdge = 45
targetX = boxEdge
targetY = boxEdge
startingCorner = {"x":boxEdge, "y":boxEdge}
foundCorner = false
doneWithField = false

angleBetween = function(aX, aY, bX, bY)
    return atan(bY - aY, bX - aX)
end function

radToDeg = function(radians)
    return radians * 180 / pi
end function

facePosition = function(x, y)
    angle = radToDeg(angleBetween(position.x, position.y, x, y))
    globals.heading = angle
end function

goToCorner = function()
    if position.x < 0 then globals.targetX = -boxEdge
    if position.y < 0 then globals.targetY = -boxEdge
    startingCorner.x = targetX
    startingCorner.y = targetY
    facePosition targetX, targetY
end function

goToCorner

while deerCount > 1
    if abs(position.x - targetX) < 2 and abs(position.y - targetY) < 2 then
        if doneWithField then
            print "Hiss hissshss!"
            if position.x < 0 and position.y < 0 then 
                targetY = 50
            else if position.x < 0 and position.y > 0 then 
                targetX = 50
            else if position.x > 0 and position.y > 0 then 
                targetY = -50
            else if position.x > 0 and position.y < 0 then 
                targetX = -50
            end if
        else 
            if foundCorner then
                if abs(position.x - startingCorner.x * -1) < 5 and abs(position.y - startingCorner.y * -1) < 5 then
                    doneWithField = true;
                    speed = 33
                    yield
                    continue
                end if
                if startingCorner.x < 0 then 
                    targetX = targetX + 5
                else
                    targetX = targetX - 5
                end if
            end if
            if targetY < 0 then 
                targetY = boxEdge
            else
                targetY = -boxEdge
            end if
            speed = 14
            foundCorner = true
        end if
    end if
    facePosition targetX, targetY

    if not doneWithField and foundCorner and energy > 10 and ticks % 40 == 0 then 
        if boxEdge - abs(position.x) > 1 and boxEdge - abs(position.y) > 1 then drop 1, 1
    end if

    ticks = ticks + 1
    yield
end while

jstrout

Looks great Max! I look forward to meeting your robo-reindeer on the snowy battlefield!

jstrout

I present to you... Miner!

// Name: Miner

pointAt = function(x, y)
    globals.heading = atan(y - position.y, x - position.x) * 180/pi
end function

goTo = function(x, y, radius=5, dropMines=true)
    print "Going to " + x + "," + y
    nextDropTime = 0
    while true
        dist = sqrt((position.x - x)^2 + (position.y - y)^2)
        if dist > radius then
            pointAt x, y
            globals.speed = 50
        else
            if speed == 50 then print "Arrived"
            globals.speed = 0
            if actual.speed < 1 then break
        end if
        yield
        if dropMines and speed > 30 and energy > 30 and time > nextDropTime then
            drop 2
            nextDropTime = time + 0.2
        end if
    end while
end function

recover = function()
    while energy < 50
        wait
    end while
end function

r = 45
first = true
while true
    goTo r, r, 5, not first; recover; first = false
    goTo r, -r; recover
    goTo -r, -r; recover
    goTo -r, r; recover
    r = r - 5
    if r < 10 then r = 45
end while

jstrout

And another: Corner Lurker!

// Name: CornerLurker

heading = 225
speed = 100
while position.x > -48 or position.y > -48; wait; end while
speed = 0
wait

turnTo = function(newHeading)
    globals.heading = newHeading
    while actual.heading != newHeading
        yield
    end while
end function

carefulAim = function()
    print "Aiming..."
    maxAng = actual.heading; minAng = maxAng
    while look != null and minAng > 0 and minAng < 90
        minAng = actual.heading
        turnTo minAng - 2
    end while
    turnTo maxAng
    while look != null and maxAng > 0 and maxAng < 90
        maxAng = actual.heading
        turnTo maxAng + 2
    end while
    turnTo (minAng + maxAng) / 2
    print "Aim " + round(minAng) + " to " + round(maxAng)
    return true
end function

check = function()
    info = look
    if info == null then return
    e = energy / 2
    // if enemy is stalled (negitave energy), it can't dodge,
    // so hit harder
    if info.energy < -5 or info.speed < 1 then
        if not carefulAim then return
        e = info.health
        if energy - e < -50 then e = energy + 50
    end if
    throw e
end function

while true
    for heading in range(90, 0, -5)
        yield
        check
    end for
    for heading in range(0, 90, 5)
        yield
        check
    end for
end while

jstrout

The results are in:

Kudos to @maxkratt for a strong showing! His "Roundabout Rosy" was very difficult to hit, and "Snakey Simon" was very thorough with the meadow mines!

We're already talking (on Discord) about making some changes to the game for next year. Keep watching and feel free to put in your $0.02 worth. I hope to see your entries next year!